#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.2.4.9
 Author:         CEoCEo
 Credits:        BoardBabe, IT Troll, mr_smartepants, Shark007

 Script Function: 1.51
	'Nero Burning ROM 7.10.1.0' unattended AutoIt script.

	- Leave this script in the same dir as the executables and you are set to go.
		Either compile this script with AutoIt - http://www.autoitscript.com/autoit3
		or put AutoIt3.exe in any %PATH% environment variable and call 'AutoIt3.exe scriptname.au3'
	- History is found last in this script.
	- This script can handle Multilanguage distributions.
	- If there are any problems or suggestions regarding this script, write in this topic:
		http://www.msfn.org/board/index.php?showtopic=56208
	- Updated versions of this script can be found here:
		http://www.msfn.org/board/index.php?showtopic=20197&view=findpost&p=664489

	Please edit serial, username, components and switches to your liking below.

#ce ----------------------------------------------------------------------------

$ID = ""; Custom installation path example: $ID = "D:\Program Files\Nero"
$SN = "xxxx-xxxx-xxxx-xxxx-xxxx-xxxx-xxxx"; Nero Serial Number
$PI = ""; Add serials for your plug-ins separated by a comma "," to activate them
$UN = "UserName"
$CN = "CompanyName"

$16 = 0	; Nero Home
$4E = 1	; StartSmart
$04 = 1	; Burning ROM + Express
$59 = 1	; Vision
$29 = 0	; BackItUp
$26 = 1	; CoverDesigner
$7B = 1	; WaveEditor
$46 = 0	; SoundTrax
$E2 = 0	; ShowTime
$20 = 0	; MediaHome
$0C = 1	; Recode
$52 = 0	; Photosnap + Viewer
$8F = 0	; BurnRights
$06 = 0	; ImageDrive
$E0 = 1	; CD-DVD Speed
$12 = 1	; DriveSpeed
$4A = 1	; InfoTool
$D8 = 1	; Burn/Burn Settings Plug-In for MCE
$B3 = 1	; Media Streaming
$69 = 0	; Mobile

$ASK = 0	; Install Ask Toolbar
$SCO = 0	; Install Nero Scout
$HLP = 1	; Install Help files
$NV4 = 1	; Install Template Package for Nero Vision 4
$NFC = 0	; Autostart Nero Filter Check
$EAU = 0	; Enable Automatic Update
$AUD = 30	; Change number of days before Nero checks for updates
$SND = 0	; Enable all sounds in Burning ROM
$TWS = 1	; Show temporary writing speed
$EAC = 1	; Enable all compilations
$EDO = 0	; Enable DVD overburning
$ESL = 0	; Enable generation of short lead-out
$ECD = 0	; Prevent the CD/DVD from ejecting after burning is complete
$VWD = 0	; Verify Written Data after burning is complete
$SSS = 1	; StartSmart: Show left panel
$SSA = 1	; StartSmart: Advanced Mode
$RBR = 0	; Run BurnRights to allow all users logged on locally to burn media
$RFA = 0	; Reset File Associations created by Nero ShowTime

$OSD = 0	; Delete Nero Online Upgrade Offering Desktop shortcut
$OSS = 0	; Delete Nero Online Upgrade Offering Start Menu shortcut
$DPS = 0	; Delete Nero ProductSetup Start Menu shortcut
$DSS = 0	; Delete Nero StartSmart Desktop shortcut
$QSS = 0	; Delete Nero StartSmart QuickLaunch shortcut
$DNH = 0	; Delete Nero Home Desktop shortcut
$QNH = 0	; Delete Nero Home QuickLaunch shortcut

#cs ----------------------------------------------------------------------------

 Script Start!

#ce ----------------------------------------------------------------------------

Dim $I, $D, $P
If $16 = 0 Then $I = $I & "C2FF8B816=0 "
If $4E = 0 Then $I = $I & "CB035464E=0 "
If $04 = 0 Then $I = $I & "CBCAFF604=0 "
If $59 = 0 Then $I = $I & "C57D52359=0 "
If $29 = 0 Then $I = $I & "CCB9D5429=0 "
If $26 = 0 Then $I = $I & "C7CE8D626=0 "
If $7B = 0 Then $I = $I & "CFA3A3F7B=0 "
If $46 = 0 Then $I = $I & "C716FE146=0 "
If $E2 = 0 Then $I = $I & "CD773A6E2=0 "
If $20 = 0 Then $I = $I & "C53BEFA20=0 "
If $0C = 0 Then $I = $I & "C6035F00C=0 "
If $52 = 0 Then $I = $I & "CED1EAF52=0 "
If $8F = 0 Then $I = $I & "C72CC518F=0 "
If $06 = 0 Then $I = $I & "CE38B9E06=0 "
If $E0 = 0 Then $I = $I & "C82602EE0=0 "
If $12 = 0 Then $I = $I & "C7DFFCC12=0 "
If $4A = 0 Then $I = $I & "CE72D824A=0 "
If $D8 = 0 Then $I = $I & "C5AD292D8=0 "
If $B3 = 0 Then $I = $I & "C79061EB3=0 "
If $69 = 0 Then $I = $I & "C91F9B069=0 "

If FileExists ( @CommonFilesDir & "\Ahead\Lib\AdvrCntr2.dll" ) Then
	MsgBox ( 0x40010, @ScriptName, "Please uninstall previous version of Nero before using this script", 3 )
	Exit
EndIf

; Clean up existing Nero temporary files
$search = FileFindFirstFile ( @TempDir & "\NER*.*" )
While 1
	$TMP = FileFindNextFile ( $search )
	If @error Then ExitLoop
	DirRemove ( @TempDir & "\" & $TMP, 1)
WEnd
FileClose ( $search )

; Search distribution
$search = FileFindFirstFile ( @ScriptDir & "\Nero-7*.exe" )
$SF = FileFindNextFile ( $search )

; Run installer
If $search = 1 Then
	If Not $ID = "" Then $D = "INSTALLDIR=" & Chr ( 34 ) & $ID & Chr ( 34 ) & " "
	Run ( @ScriptDir & "\" & $SF & " /qb! /NORESTART RebootYesNo=No SERIALNUM_USERVAL=" & $SN & " AgreeToLicense=Yes EULA_AGREEMENT=1 " & $D & $I )
Else
	MsgBox ( 0x40010, @ScriptName, "Nero executable not found", 3 )
	Exit
EndIf

; Search extraction dir
Sleep ( 5000 )
$search = FileFindFirstFile ( @TempDir & "\NER*.*" )
$dir = FileFindNextFile ( $search )
$path = @TempDir & "\" & $dir

AdlibEnable ( "Toolbar" )
ProcessWait ( "SetupX.exe" )
AdlibDisable()

; Delete configuration file to enable custom installation
FileDelete ( $path & "\Redist\Config\conf.txt" )

; Delete (The Weather Channel Desktop) installer to prevent execution
FileDelete ( $path & "\Redist\NeroWeatherChannelDesktop\Weather Channel Installer.exe" )

; Update DirectX during setup if necessary
$DX = $path & "\Redist\DirectX\dxsetup.exe"
If Not FileExists ( @SystemDir & "\d3dx9_28.dll" ) Or Not FileExists ( @SystemDir & "\d3dx9_30.dll" ) And FileExists ( $DX ) Then Run ( $DX & " /silent" )

ProcessWaitClose ( "SetupX.exe" )
$TP = RegRead ( "HKLM\SOFTWARE\Ahead\Installation\Families\Nero 7", "TargetPath" )

; Search for Nero 7 Helpfile Pack
$search = FileFindFirstFile ( @ScriptDir & "\Nero7_chm_*.exe" )
$HF = FileFindNextFile ( $search )

; Install Nero 7 Helpfile Pack
If $HLP = 1 And $search = 3 And $ID = "" Then
	RunWait ( @ComSpec & " /c " & "del /q /s *.chm", $TP, @SW_HIDE); Search and delete all Help files
	RunWait ( @ScriptDir & "\" & $HF & " /S" )
EndIf

; Install Template Package for Nero Vision 4
If $NV4 = 1 And $59 = 1 And $ID = "" And FileExists ( @ScriptDir & "\NV4content.exe" ) Then RunWait ( @ScriptDir & "\NV4content.exe /S" )

; Handle Nero SFX installers if custom installation path is modified
If Not $ID = "" Then
	If $HLP = 1 Or $NV4 = 1 Then DirRemove ( @ProgramFilesDir & "\Nero", 1 )
	If $HLP = 1 And $search = 3 Then RunWait ( @ScriptDir & "\" & $HF & " /S" )
	If $NV4 = 1 And $59 = 1 And FileExists ( @ScriptDir & "\NV4content.exe" ) Then RunWait ( @ScriptDir & "\NV4content.exe /S" )
	If $HLP = 1 Or $NV4 = 1 Then RunWait ( @ComSpec & " /c " & "xcopy /EQY " & Chr ( 34 ) & "Nero 7" & Chr ( 34 ) & " " & Chr ( 34 ) & $ID & Chr ( 34 ), @ProgramFilesDir & "\Nero", @SW_HIDE )
	If $HLP = 1 Or $NV4 = 1 Then DirRemove ( @ProgramFilesDir & "\Nero", 1 )
EndIf

; Apply username
RegWrite ( "HKLM\SOFTWARE\Ahead\Installation\Families\Nero 7\Info", "User", "REG_SZ", $UN )
RegWrite ( "HKLM\SOFTWARE\Ahead\Installation\Families\Plugins\Info", "User", "REG_SZ", $UN )
RegWrite ( "HKLM\SOFTWARE\Ahead\Installation\Families\Nero 7\Info", "Company", "REG_SZ", $CN )
RegWrite ( "HKLM\SOFTWARE\Ahead\Installation\Families\Plugins\Info", "Company", "REG_SZ", $CN )

; Activate plugins
If Not $PI = "" Then
	$PI = StringSplit ( $PI, ",")
	Do
		$P = $P + 1
		RegWrite ( "HKLM\SOFTWARE\Ahead\Installation\Families\Plugins\Info", "Serial7_" & $P, "REG_SZ", "*" & $PI[$P] )
	Until $P = $PI[0]
EndIf

; Nero Scout removal
If $SCO = 0 Then
	; Deletes Nero Scout Optionswizard from Autostart
	RegDelete ( "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce", "NeroHomeFirstStart" )

	; Disable Nero Scout in Explorer
	RegDelete ( "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\MyComputer\NameSpace\{3d6be802-fc0d-4595-a304-e611f97089dc}" )

	; Disable Nero Scout
	RegWrite ( "HKLM\SOFTWARE\Ahead\Nero Home\MediaLibrary", "DisableNeroScout", "REG_DWORD", 1 )

	; Delete Nero Scout executable to prevent execution
	FileDelete ( @CommonFilesDir & "\Ahead\Lib\NeroScoutOptions.exe" )

	; Search and delete Nero Scout shortcut
	Run ( @ComSpec & " /c " & "del /q /s NEROSC~1.LNK", @ProgramsCommonDir, @SW_HIDE )
EndIf

; Apply settings
$KE1 = "HKCU\SOFTWARE\Ahead\Nero - Burning Rom"
$KE2 = "HKCU\SOFTWARE\Ahead\Nero StartSmart\Settings"
If $NFC = 0 Then RegDelete ( "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "NeroFilterCheck" )
If $EAU = 0 Then RegWrite ( "HKLM\SOFTWARE\Ahead\Installation\Settings", "AutomaticUpdate", "REG_DWORD", 0 )
If Not $AUD = 0 And $EAU = 1 Then RegWrite ( "HKLM\SOFTWARE\Ahead\Installation\Settings", "LastUserAutomaticUpdateDays", "REG_DWORD", $AUD )
If $SND = 1 Then
	RegWrite ( $KE1 & "\General", "CdChangeCheck", "REG_DWORD", 1 )
	RegWrite ( $KE1 & "\General", "CdFailCheck", "REG_DWORD", 1 )
	RegWrite ( $KE1 & "\General", "CdSuccessCheck", "REG_DWORD", 1 )
EndIf
If $TWS = 1 Then RegWrite ( $KE1 & "\Recorder", "ShowSingleRecorderSpeed", "REG_DWORD", 1 )
If $EAC = 1 Then RegWrite ( $KE1 & "\General", "bShowAllCompilationTypes", "REG_DWORD", 1 )
If $EDO = 1 Then RegWrite ( $KE1 & "\General", "EnableDVDOverSize", "REG_DWORD", 1 )
If $ESL = 1 Then RegWrite ( $KE1 & "\Recorder", "ShortLeadOut", "REG_DWORD", 375 )
If $ECD = 1 Then RegWrite ( $KE1 & "\General", "EjectTheCDLater", "REG_DWORD", 1 )
If $VWD = 1 Then RegWrite ( $KE1 & "\General", "UseVerifyAfterBurn", "REG_DWORD", 1 )
If $SSS = 1 And $4E = 1 Then RegWrite ( $KE2, "DisplayLeftPanel", "REG_DWORD", 1 )
If $SSA = 1 And $4E = 1 Then RegWrite ( $KE2, "AdvancedMode", "REG_DWORD", 1 )
If $RBR = 1 And $8F = 1 Then RunWait ( $TP & "Nero Toolkit\NeroBurnRights.exe /all" )

; Reset File Associations created by Nero ShowTime
If $RFA = 1 And $E2 = 1 Then
	RegWrite ( "HKCR\.aif", "", "REG_SZ", "AIFFFile" )
	RegWrite ( "HKCR\.aifc", "", "REG_SZ", "AIFFFile" )
	RegWrite ( "HKCR\.aiff", "", "REG_SZ", "AIFFFile" )
	RegWrite ( "HKCR\.avi", "", "REG_SZ", "avifile" )
	RegWrite ( "HKCR\.m1v", "", "REG_SZ", "mpegfile" )
	RegWrite ( "HKCR\.m3u", "", "REG_SZ", "m3ufile" )
	RegWrite ( "HKCR\.mid", "", "REG_SZ", "midfile" )
	RegWrite ( "HKCR\.midi", "", "REG_SZ", "midfile" )
	RegWrite ( "HKCR\.mp2", "", "REG_SZ", "mpegfile" )
	RegWrite ( "HKCR\.mp3", "", "REG_SZ", "mp3file" )
	RegWrite ( "HKCR\.mpa", "", "REG_SZ", "mpegfile" )
	RegWrite ( "HKCR\.mpeg", "", "REG_SZ", "mpegfile" )
	RegWrite ( "HKCR\.mpg", "", "REG_SZ", "mpegfile" )
	RegWrite ( "HKCR\.rmi", "", "REG_SZ", "midfile" )
	RegWrite ( "HKCR\.wav", "", "REG_SZ", "soundrec" )
	RegWrite ( "HKCR\.wma", "", "REG_SZ", "WMAFile" )
	RegWrite ( "HKCR\.wmv", "", "REG_SZ", "WMVFile" )
EndIf

; Remove shortcuts
$QL = @AppDataDir & "\Microsoft\Internet Explorer\Quick Launch"
If $OSD = 1 Then FileDelete ( @DesktopCommonDir & "\ONLINE~1.LNK" )
If $OSS = 1 Then Run ( @ComSpec & " /c " & "del /q /s ONLINE~1.LNK", @ProgramsCommonDir, @SW_HIDE )
If $DPS = 1 Then Run ( @ComSpec & " /c " & "del /q /s NEROPR~1.LNK", @ProgramsCommonDir, @SW_HIDE )
If $DSS = 1 Then FileDelete ( @DesktopCommonDir & "\Nero StartSmart.lnk" )
If $QSS = 1 Then FileDelete ( $QL & "\Nero StartSmart.lnk" )
If $DNH = 1 Then FileDelete ( @DesktopCommonDir & "\Nero Home.lnk" )
If $QNH = 1 Then FileDelete ( $QL & "\Nero Home.lnk" )

; Close the search handle
FileClose ( $search )

; Remove temporary files
DirRemove ( $path, 1 )
FileDelete ( @TempDir & "\*.tmp" )

; Handle Ask Toolbar installer
Func Toolbar()
	If WinActive ( "Nero Ask Toolbar" ) And $ASK = 1 Then ControlClick ( "Nero", "", "Button4" )
	If WinActive ( "Nero Ask Toolbar" ) And $ASK = 0 Then
		ControlClick ( "Nero", "", "Button2" )
		ControlClick ( "Nero", "", "Button4" )
	EndIf
EndFunc

#cs ----------------------------------------------------------------------------

 History: 'Nero Burning ROM 7.10.1.0' unattended AutoIt script.

 Version: 1.51 (minor update)
	* Updated: Delete (The Weather Channel Desktop) installer to prevent execution

 Version: 1.5
	* Added: Optional install of Template Package for Nero Vision 4 (NV4content.exe)
	* Added: Special treatment of SFX packs when using a custom installation path
	* Added: Ability to activate additional Plug-ins
	* Added: Option to set Advanced Mode in StartSmart
	* Added: Option to run BurnRights to allow all users logged on locally to burn media
	* Added: Option to change number of days before Nero checks for updates

 Version: 1.4
	* Updated: Support for different version of 'Nero Burning ROM 7.10.1.0' featuring (The Weather Channel Desktop)
	* Updated: Only update DirectX if necessary
	* Added: Option to specify a custom installation path
	* Added: Clean up temporary files before installation starts
	* Added: Exit script if Nero is already installed
	* Added: Option to Delete Nero ProductSetup shortcut
	* Added: Option to Delete Nero Online Upgrade Offering shortcuts
	* Added: Option to Reset File Associations created by Nero ShowTime
	* Removed: Obsolete component (Fast CD-DVD Burning Plug-In for WMP)

 Version: 1.31 (minor update)
	* Updated: Support for 'Nero Burning ROM 7.10.1.0'

 Version: 1.3
	* Fixed: Improved 'Ask Toolbar' management
	* Updated: More tweaks and improvements

 Version: 1.2
	* Added: Automatic search and install of distribution (Nero-7.9.6.0_*.exe)
	* Added: Automatic search and optional install of help file (Nero7_chm_*.exe)
	* Added: Exclude components via command line
	* Updated: Few more tweaks and improvements
	* Removed: Removed dependency to 'conf.txt'

 Version: 1.1
	* Added: Handle 'Ask Toolbar' if it is found in the distribution (mainly English users)
	* Added: Delete 'Nero Scout' in StartSmart to prevent execution
	* Updated: More tweaks and improvements
	
 Version: 1.0
	'Nero Burning ROM 7.9.6.0' initial release
	Unattended script for Swedish and possibly other language distristributions.
	Script based on configurationfile 'conf.txt'

#ce ----------------------------------------------------------------------------