Archive - February 2012

"Great hopes make great men." - Thomas Fuller

Index

Retrieving SKU for Win7
Display NIC Speed
Flashing Keyboard Keys
Install Printer - Auto-elevation
Salvador Dali Clock
UAC - on
Enumerate Reg Hive Keys

Color Progress Bar
Cloning a Timestamp
Excuses
Add VBS to Right-click Context Menu
HTA and DIV Power

Δ Wednesday, February 29th, 2012

Δ Retrieving SKU for Win7

How to return SKU

[download resource files]

Demo

Return the SKU of a Windows 7 machine using WMI.

Δ [email me]

Δ Monday, February 27th, 2012

Δ Display NIC Speed

How to return NIC speed

[download resource files]

Demo

Return the speed of all NICs using the class Win32_ComputerSyste from WMI.

On Error Resume Next

Select Case WScript.Arguments.UnNamed.Count
	Case 0
		Set objWMIService = GetObject( "winmgmts://./root/cimv2" )
		Set colItems = objWMIService.ExecQuery( "Select * from Win32_ComputerSystem", , wbemFlagReturnImmediately + wbemFlagForwardOnly )
		For Each objItem in colItems
			strComputer = objItem.Name
		Next
	Case 1
		strComputer = WScript.Arguments.UnNamed(0)
	Case Else
		Syntax( )
End Select

Const wbemFlagReturnImmediately = &h10
Const wbemFlagForwardOnly = &h20

Set objWMIService = GetObject( "winmgmts://" & strComputer & "/root/WMI" )
Set colItems      = objWMIService.ExecQuery( "SELECT * FROM MSNdis_EthernetCurrentAddress WHERE Active = True", "WQL", wbemFlagReturnImmediately + wbemFlagForwardOnly )
For Each objItem In colItems
	strMsg = strMsg & "Ethernet Adapter : " & objItem.InstanceName      & vbCrLf
	Set col2Items = objWMIService.ExecQuery("SELECT * FROM MSNdis_LinkSpeed WHERE InstanceName = '" & objItem.InstanceName & "'", "WQL", wbemFlagReturnImmediately + wbemFlagForwardOnly)
	For Each obj2Item In col2Items
		strMsg = strMsg & "NDIS Link Speed  : " & obj2Item.NdisLinkSpeed & " kBps" & vbCrLf
	Next
	strMsg = strMsg & vbCrLf
Next
WScript.Echo strMsg

Sub Syntax( )
	strMsg = strMsg & vbCrLf _
	       & "NICSpeed.vbs,  Version 1.00" & vbCrLf _
	       & "Display network adapter link speed for " _
	       & "any WMI enabled computer on the network" & vbCrLf & vbCrLf _
	       & "Usage:  CSCRIPT  //NOLOGO  NICSPEED.VBS  " _
	       & "[ computer_name ]" & vbCrLf & vbCrLf _
	       & "Where:  " & Chr(34) & "computer_name" & Chr(34) _
	       & " is the optional name of a remote computer" & vbCrLf _
	       & "                        (default is the local computer " _
	       & "name)" & vbCrLf & vbCrLf _
	       & "Created with Microsoft's Scriptomatic tool" & vbCrLf _
	       & "http://www.microsoft.com/technet/treeview/default.asp" _
	       & "?url=/technet/scriptcenter/WMImatic.asp" & vbCrLf
	WScript.Echo strMsg
	WScript.Quit(1)
End Sub

Δ [email me]

Δ Thursday, February 23rd, 2012

Δ Flashing Keyboard Keys

How to light up keys on your keyboard.

[download resource files]

Using sendkeys to light up keys on the keyboard. I put this in a loop and use it to stop a
machine from going into sleep/standby mode. This will also stop the screensaver from
being triggered.

Δ [email me]

Δ Tuesday, February 21st, 2012

Δ Install Printer - Auto-elevation

How to install printers

[download resource files]

This will install printers on Windows 7 with built-in elevation. I use this to get around Win7
prompts. You could also use group policy.

Δ [email me]

Δ Friday, February 17th, 2012

Δ Salvador Dali Clock

How to create a Dali Clock

[download resource files]

Demo

This will create a very cool, changing Dali clock.

<HTML><HEAD><TITLE>Salvador Dali Clock</TITLE>
<HTA:APPLICATION CONTEXTMENU="no" MAXIMIZEBUTTON = "No" MINIMIZEBUTTON = "No" BORDER="Thin" />
<STYLE type="text/css"></STYLE>
<XML:NAMESPACE NS="urn:schemas-microsoft-com:vml" PREFIX="v" /></HEAD>
<BODY SCROLL="no" STYLE="margin:0px"><DIV ID="htmBuild"></DIV></BODY>

<SCRIPT LANGUAGE="VBScript">
Option Explicit 
Randomize Timer

Dim vmlShape(6),IntervalSecond,L,S

'---- VML shape data'
Dim Paths 
Paths = Array("M32,0 C73,2 73,62 32,64 M32,0 C-9,2 -9,62 32,64", _
"M32,0 L32,64 M1,32 L63,32 M16,5 L48,59 M48,5 L16,59 M5,16 L59,47 M5,48 L59,16", _
"M32,8 C63,10 63,56 32,56 M32,8 C1,8 1,56 32,56", "M32,4 L31,20 32,32 33,20 X", _
"M32,16 L31,20 32,32 33,20 X","66,90 32,65 76,65 78,32 66,79 78,68","M32,3 L32,32")

'---- Build VML shapes'
For L=0 to 6 : S=S & "<V:SHAPE ID='vmls" & L & "'></V:SHAPE>" : Next
htmBuild.InnerHTML=S
For L=0 to 6
Set vmlShape(L)=Document.GetElementByID("vmls" & L)
With vmlShape(L)
.Style.Position="Absolute" : .Style.Width="100%" : .Style.Height="100%"
.StrokeWeight=2 : .StrokeColor=Int(Rnd(1)*&H606060)
.CoordSize="64 64" : .Path=Paths(L) : .FillColor = Int(Rnd(1)*&HFFFFFF)
If L=0 or L=2 then .FillColor="white" : If L Then .StrokeColor="white"
End With
Next
Document.Body.BGColor = Int(Rnd(1)*&HFFFFFF)

'---- Wave FX....Remove this for a normal looking clock'
With htmBuild
.Style.Position="Absolute":.Style.Width="100%":.Style.Height="100%":.Style.left=-15
.Style.Filter="ProgID:DXImageTransform.Microsoft.Wave" : .Filters(0).Freq=2 :
.Filters(0).Strength=15 : .Filters(0).LightStrength=20 : .Filters(0).Phase=Int(Rnd(1)*100)
End With
'---- ^ Remove'

'---- Refresh hands right away and start interval'
MoveHands() : Self.ResizeTo 390,370 : Self.MoveTo (Screen.Width/2)-175,(Screen.Height/2)-185
IntervalSecond = Window.SetInterval ("MoveHands", 1000) '<-- Update every second (no point being shorter)'

'---- Set rotation to time (360/60=6, the hour is a bit tricky though)'
Sub MoveHands()
vmlShape(6).Rotation=Second(Now)*6
vmlShape(3).Rotation=Minute(Now)*6 '<-- Fine rotation not needed on minutes'
vmlShape(4).Rotation=Hour(Now)*30 + (Minute(Now)/2.5) '<-- Needed for hours though'
End Sub

</SCRIPT></HTML>

Δ [email me]

Δ Thursday, February 16th, 2012

Δ UAC - on

How to enable UAC

[download resource files]

Adjust the Windows 7 UAC.

Δ [email me]

Δ Monday, February 13th, 2012

Δ Enumerate Reg Hive Keys

How to enumerate hive keys

[download resource files]

Demo

Enumerate reg keys. You could use this to perform other processes on each returned hive key.

Δ [email me]

Δ Friday, February 10th, 2012

Δ Color Progress Bar

How to add color to a progress bar

[download resource files]

Demo

Yet another progress bar that adds a little color to the HTA.

<html> 
<head> 
<title> 
Please Wait... 
</title>

<HTA:APPLICATION 
ID="objNoTitleBar" 
APPLICATIONNAME="Please Wait..." 
SCROLL="no" 
SINGLEINSTANCE="yes" 
CAPTION="no" 
BORDER="Thin" 
BORDERSTYLE="complex" 
SHOWINTASKBAR="no" 
CONTEXTMENU="no" 
> 
</head> 
<SCRIPT LANGUAGE="VBScript"> 
Dim iTimerID

Sub CloseWindow 
if window.event.keyCode = 27 Then 
self.close 
End if 
End Sub

Sub Window_Onload 
iTimerID = window.setInterval("Display_Progress", 200) 
strComputer = "." 
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2") 
Set colItems = objWMIService.ExecQuery("Select * From Win32_DesktopMonitor") 
For Each objItem in colItems 
intHorizontal = objItem.ScreenWidth 
intVertical = objItem.ScreenHeight 
Next 
intLeft = (intHorizontal - 430) / 2 
intTop = (intVertical - 60) / 2 
window.resizeTo 430,60 
window.moveTo intLeft, intTop 
call Display_Progress 
End Sub

Sub Display_Progress 
If ProgressBar1.Value = ProgressBar1.Max Then 
window.clearInterval(iTimerID) 
self.close 
Else 
ProgressBar1.Value = ProgressBar1.Value + 1 
End if 
End Sub 
</SCRIPT> 
<body onkeypress='CloseWindow' 
STYLE="font:14 pt arial; color:white; 
filter:progid:DXImageTransform.Microsoft.Gradient 
(GradientType=1, StartColorStr='#FF0000', EndColorStr='#00FF00')" 
> 
<object classid="clsid:35053A22-8589-11D1-B16A-00C0F0283628" id="ProgressBar1" height="20" width="400"> 
<param name="Min" value="0"> 
<param name="Max" value="100"> 
<param name="Orientation" value="0"> 
<param name="Scrolling" value="1"> 
</object> 
</body>

</html>

Δ [email me]

Δ Wednesday, February 8th, 2012

Δ Cloning a Timestamp

How to clone a timestamp

[download resource files]

Clone the timestamp of a file. Can be used to guarantee timestamps match after an archiving
task has been completed.

Option Explicit

' Lots and lots of variables, most of them required to allow wildcards
Dim arrTgtFiles
Dim dtmFileDate
Dim i
Dim colTgtFiles, objFile, objFolder, objFSO, objRegEx, objShell
Dim objFSTgtFolder, objSrcFile, objSrcFolder, objTgtFile, objTgtFolder
Dim strSrcFile, strSrcFolder, strTgtFiles, strTgtFolder, strTgtStr

' We'll use the Windows Shell as well as the FileSystem Object to handle files
Set objFSO   = CreateObject( "Scripting.FileSystemObject" )
Set objShell = CreateObject( "Shell.Application" )
' A Regular Expression is used to check if file names match wildcards
Set objRegEx = New RegExp
objRegEx.IgnoreCase = True
objRegEx.Global     = True

With WScript.Arguments
	' 2 command line arguments are required
	If .Named.Count    > 0 Then Syntax
	If .Unnamed.Count <> 2 Then Syntax
	If Not objFSO.FileExists( .Unnamed(0) ) Then Syntax
	strSrcFolder = objFSO.GetParentFolderName( objFSO.GetAbsolutePathName( .Unnamed(0) ) )
	Set objSrcFolder = objShell.NameSpace( strSrcFolder )
	strTgtFolder = objFSO.GetParentFolderName( objFSO.GetAbsolutePathName( .Unnamed(1) ) )
	Set objTgtFolder = objShell.NameSpace( strTgtFolder )
	strSrcFile = objFSO.GetFileName( .Unnamed(0) )
	Set objSrcFile = objSrcFolder.ParseName( strSrcFile )
	dtmFileDate = objSrcFile.ModifyDate
	If InStr( .Unnamed(1), "?" ) Or InStr( .Unnamed(1), "*" ) Then
		' Handle wildcards in the target filespec
		strTgtFolder = objFSO.GetAbsolutePathName( .Unnamed(1) & "\.." )
		If Not objFSO.FolderExists( strTgtFolder ) Then Syntax
		Set objFSTgtFolder = objFSO.GetFolder( strTgtFolder )
		If objFSTgtFolder.Files.Count < 1 Then Syntax
		arrTgtFiles = Split( .Unnamed(1), "\" )
		strTgtFiles = arrTgtFiles( UBound( arrTgtFiles ) )
		' Convert the filespec with DOS wildcards to a RegEx pattern
		objRegEx.Pattern = "^" & Replace( strTgtFiles, "*", "\w*" )
		objRegEx.Pattern = Replace( objRegEx.Pattern, "$", "\$" )
		objRegEx.Pattern = Replace( objRegEx.Pattern, "?", "\w?" ) & "$"
		strTgtStr = ""
		For Each objFile In objFSTgtFolder.Files
			If objRegEx.Test( objFile.Name ) Then
				If LCase( objFile.Name ) <> LCase( strSrcFile ) Then
					If objFSO.FileExists( objFile.Path ) Then
						strTgtStr = strTgtStr & "," & objFile.Name
					End If
				End If
			End If
		Next
		If strTgtStr = "" Then Syntax
		strTgtStr   = Mid( strTgtStr, 2 )
		arrTgtFiles = Split( strTgtStr, "," )
	Else
		' Single target file
		If Not objFSO.FileExists( .Unnamed(1) ) Then Syntax
		strTgtFiles = objFSO.GetFileName( .Unnamed(1) )
		arrTgtFiles = Array( strTgtFiles )
	End If
	' For every matching file . . .
	For i = 0 To UBound( arrTgtFiles )
		Set objTgtFile = objTgtFolder.ParseName( arrTgtFiles(i) )
		' . . . change the timestamp (LastModified date)
		objTgtFile.ModifyDate = dtmFileDate
	Next
End With

Set objRegEx = Nothing
Set objShell = Nothing
Set objFSO   = Nothing

Sub Syntax
	Dim strMsg
	strMsg = "CloneDate,  Version 2.10" _
	       & vbCrLf _
	       & "Modify the LastModified date (timestamp) of the target file(s) to" _
	       & vbCrLf _
	       & "match the specified source file's timestamp" _
	       & vbCrLf & vbCrLf _
	       & "Usage:    CLONEDATE.VBS  sourcefile targetfiles" _
	       & vbCrLf & vbCrLf _
	       & "Where:    ""sourcefile""   is the file whose timestamp is to be cloned" _
	       & vbCrLf _
	       & "          ""targetfiles""  is (are) the file(s) whose timestamp is to" _
	       & vbCrLf _
	       & "                         be modified (wildcards * and ? are allowed)" _
	       & vbCrLf & vbCrLf _
	       & "Example:  CLONEDATE.VBS  C:\boot.ini  C:\test.log" _
	       & vbCrLf _
	       & "          will change C:\test.log's timestamp" _
	       & vbCrLf & vbCrLf _
	       & "Notes:    sourcefile may be hidden, but hidden targetfiles will be skipped." 
	       WScript.Echo strMsg
	WScript.Quit 1
End Sub

Δ [email me]

Δ Tuesday, February 7th, 2012

Δ Excuses

How to return excuses

[download resource files]

Demo

Used to generate random excuses from a text list. Could easily be changed to return quote of
the day.

Δ [email me]

Δ Friday, February 3rd, 2012

Δ Add VBS to Right-click Context Menu

How to add an item to the context menu

[download resource files]

Demo

This will allow you to right-click and select VBS to create a new VBScript.

Δ [email me]

Δ Wednesday, February 1st, 2012

Δ HTA and DIV Power

How to use HTA and DIVs

[download resource files]

Demo

This demonstrates the power of HTA and DIVs. This shows how to create a multi-use, single box
HTA.

<html>
<head>
<title>DIVHTA</title>

<SCRIPT LANGUAGE="VBScript">
' Set window dimentions loaded here to prevent flicker, method (c) M. Harris
window.resizeto 750,400
</SCRIPT>

<HTA:APPLICATION 
ID="Eddie Jackson"
APPLICATIONNAME="DIVHTA"
SCROLL="yes"
SINGLEINSTANCE="yes"
>

<style>
body,td a {font-family:Calibri, Veranda, Arial; font-size:16px; text-decoration:none; color:black;} 
H1 { font-family:Calibri, Veranda, Arial; font-size:20px; color : blue; }
a:link { color : yellow; background : transparent ; text-decoration: underline ; font-size:12px;} 
a:visited { color : yellow; background : transparent ; text-decoration: none ; font-size:12px;} 
a:Hover { color : red; background : transparent ; text-decoration: none ; font-size:12px;} 
</style>

<SCRIPT LANGUAGE="VBScript">

'--------------------------------------------------------------------------------

Sub Window_Onload 
' This sub runs when the application starts.

' Run SplashScreen Subroutine 
SplashScreen
End Sub

'--------------------------------------------------------------------------------

Sub SplashScreen 
' Show the splash screen and open the HTA on the Main page

' Select a small image file from your windows or winnt directory
Const sBGBmp = "url(c:\windows\Prairie Wind.bmp)"

Main.Style.Display = "none" 
PgOne.Style.Display = "none" 
PgTwo.Style.Display = "none" 
PgThree.Style.Display = "none" 
Splash.Style.Display = "inline"
Splash.Style.BackgroundImage = sBGBmp

' wait 4 seconds
sleep 4

Main.Style.Display = "inline" 
Splash.Style.Display = "none"
run_button1.disabled = true
End Sub

'--------------------------------------------------------------------------------

Sub Home
' This sub runs when the Home button is pressed

' Display HTML for Home Page only
Main.Style.Display = "inline" 
PgOne.Style.Display = "none" 
PgTwo.Style.Display = "none" 
PgThree.Style.Display = "none"

' Grey out button of currently displayed page
run_button1.disabled = true
run_button2.disabled = false
run_button3.disabled = false
run_button4.disabled = false
End Sub

'--------------------------------------------------------------------------------

Sub PageOne
' This sub runs when the Page1 button is pressed

' Display HTML for Page1 only
Main.Style.Display = "none" 
PgOne.Style.Display = "inline" 
PgTwo.Style.Display = "none" 
PgThree.Style.Display = "none"

' Grey out button of currently displayed page
run_button5.disabled = false
run_button6.disabled = true
run_button7.disabled = false
run_button8.disabled = false
End Sub

'--------------------------------------------------------------------------------

Sub PageTwo
' This sub runs when the Page2 button is pressed

' Display HTML for Page2 only
Main.Style.Display = "none" 
PgOne.Style.Display = "none" 
PgTwo.Style.Display = "inline" 
PgThree.Style.Display = "none"

' Grey out button of currently displayed page
run_button9.disabled = false
run_button10.disabled = false
run_button11.disabled = true
run_button12.disabled = false
End Sub

'--------------------------------------------------------------------------------

Sub PageThree
' This sub runs when the Page3 button is pressed

' Display HTML for Page3 only
Main.Style.Display = "none" 
PgOne.Style.Display = "none" 
PgTwo.Style.Display = "none" 
PgThree.Style.Display = "inline"

' Grey out button of currently displayed page
run_button13.disabled = false
run_button14.disabled = false
run_button15.disabled = false
run_button16.disabled = true
End Sub

'--------------------------------------------------------------------------------

Sub MyMessage
' This sub runs when the "My Message" button on page2 is pressed

msgbox "I hope this example script is useful to you in demonstrating the flexibility and "&vbcrlf&"power of using DIV code in your HTA code"
End Sub

'--------------------------------------------------------------------------------

Sub DClock
' This sub runs when the Clock button on page3 is pressed

' Activate DIV code ShowClock
ShowClock.Style.Display = "inline"

' Display the time in the HTA (cool-updated every second)
iTimerID = window.setInterval("HTAClock", 1000)
End Sub

' This needs to go into a seperate sub to stop resources getting gobbled. 
sub HTAClock

' Display the current system time
Dtime.InnerHTML = time
end sub

'--------------------------------------------------------------------------------

Sub Sleep(strSeconds) 
' sub to make the script pause for x seconds

strCmd = "%COMSPEC% /c ping -n " & strSeconds & " 127.0.0.1>nul" 
Set objShell=CreateObject("Wscript.shell") 
objShell.Run strCmd,0,1 
End Sub

'--------------------------------------------------------------------------------

sub DIVHTAClose
' when the close button is pressed on Page3 this code runs and closes the HTA

'display my splash screen
PgThree.Style.Display = "none" 
Splash.Style.Display = "inline"

' wait 2 seconds
sleep 2

' close HTA
self.close
end sub

'-------------------------------------------------------------------------------- 
</SCRIPT>

</head>

<body>

<DIV id="Splash" STYLE="Background-color:184a5a;Height:200;Width:400;Border:0.4mm solid black;position:relative;top:60;left:175;"> 
<br><br> 
<center> 
<font face="arial" color=White size=5><b><i> DIVHTA </i></b></font> 
<br> 
<a href="http://eddiejackson.net">By Eddie Jackson 2007</a> 
<br><br> 
<font color=white>Example HTA to demonstrate use of DIV </font>
</center> 
</DIV>

<DIV id="Main" STYLE="display:none;position:absolute"> 
<input id=runbutton1 class="button" type="button" value="Home" name="run_button1" onClick="Home">
<input id=runbutton2 class="button" type="button" value="Page1" name="run_button2" onClick="PageOne">
<input id=runbutton3 class="button" type="button" value="Page2" name="run_button3" onClick="PageTwo">
<input id=runbutton4 class="button" type="button" value="Page3" name="run_button4" onClick="PageThree">
<BR><BR>
<H1>Main Page</H1>
<br>
Open <input id=runbutton17 class="button" type="button" value="Splash" name="run_button17" onClick="SplashScreen"> Window
</DIV>

<DIV id="PgOne" STYLE="display:none;position:absolute"> 
<input id=runbutton5 class="button" type="button" value="Home" name="run_button5" onClick="Home">
<input id=runbutton6 class="button" type="button" value="Page1" name="run_button6" onClick="PageOne">
<input id=runbutton7 class="button" type="button" value="Page2" name="run_button7" onClick="PageTwo">
<input id=runbutton8 class="button" type="button" value="Page3" name="run_button8" onClick="PageThree">
<BR><BR>
<H1>Page 1</H1>
<br>
Simple Message Box <input id=runbutton20 class="button" type="button" value="My Message" name="run_button20" onClick="MyMessage">
</DIV>

<DIV id="PgTwo" STYLE="display:none;position:absolute"> 
<input id=runbutton9 class="button" type="button" value="Home" name="run_button9" onClick="Home">
<input id=runbutton10 class="button" type="button" value="Page1" name="run_button10" onClick="PageOne">
<input id=runbutton11 class="button" type="button" value="Page2" name="run_button11" onClick="PageTwo">
<input id=runbutton12 class="button" type="button" value="Page3" name="run_button12" onClick="PageThree">
<BR><BR>
<H1>Page 2</H1>
<br>
Show Time <input id=runbutton19 class="button" type="button" value="Clock" name="run_button19" onClick="Dclock">
</DIV>

<DIV id="PgThree" STYLE="display:none;position:absolute"> 
<input id=runbutton13 class="button" type="button" value="Home" name="run_button13" onClick="Home">
<input id=runbutton14 class="button" type="button" value="Page1" name="run_button14" onClick="PageOne">
<input id=runbutton15 class="button" type="button" value="Page2" name="run_button15" onClick="PageTwo">
<input id=runbutton16 class="button" type="button" value="Page3" name="run_button16" onClick="PageThree">
<BR><BR>
<H1>Page 3</H1>
<br>
Close Window <input id=runbutton18 class="button" type="button" value="Close" name="run_button18" onClick="DIVHTAClose">
</DIV>

<DIV id="Showclock" STYLE="display:none;position:relative;top:5;left:270;"> 
<font color=red><span id=Dtime>Eddie Jackson's Clock</span></font>
</DIV>

</body> 
</html>

Δ [email me]

About

   I'm a Computer
   Systems Engineer

   Living and Loving Life

Author